electroduendes.com

var v:Date = new Date();
// comentar al subir a produccion 
mcl.loadMovie("principal.swf");
//mcl.loadMovie("principal.swf?antiproxy="+v.getTime());
// TODO: esto es un infierno!, hay que automatizarlo!.

MovieClip.prototype._loadMovie = MovieClip.prototype.loadMovie;
MovieClip.prototype.loadMovie = function(url:String,method:String):Void {
	var con:LocalConnection = new LocalConnection();
	if(con.domain()=="localhost"){
		this._loadMovie(url, method); // si estamos en local todo igual...
	} else { // en caso contrario, que reviente el proxy
		v = new Date();
		//fix alex_wolff: si la query viene con mas variables, no nos la cargamos
		var separador:String = (url.indexOf("?")>-1) ? "&" : "?"; 
		this._loadMovie(url+separador+"antiproxy="+v, method);
	}
	con.close();
}
var p = _root.createEmptyMovieClip("contenedor", 1);
p.loadMovie("jaja.jpg");

/**
 * @author Alejanadro Sánchez Marcos
 * @usage tutorial de uso de delegate en los parsers.
 * la clase emula un parser básico y su uso común.
 */
class ParserTradicional {
	public var xml:XML;
	public var textoResultado:TextField;
	// ouch!
	public static var ruta:ParserTradicional;
	public function ParserTradicional(URL:String, textoResultado:TextField) {
		xml = new XML();
		// off!
		ruta = this;
		this.textoResultado = textoResultado;
		xml.load(URL);
		// empiezan los problemas...
		// xml.ruta = this; // ay!           
		xml.onLoad = parse;
	}
	public function parse() {
		// no tengo ruta.. mmm meto un atributo estático con la ruta
		// buff!
		trace(ruta.xml);
		ruta.mostrarXML();
	}
	public function mostrarXML() {
		textoResultado.text = xml.toString();
	}
}

import mx.utils.Delegate;
/**
* @author Alex Sanchez
* @usage tutorial de uso de delegate en los parsers.
* la clase emula un parser básico y su uso común.
*/
class ParserDelegate {
	public var xml:XML;
	public var textoResultado:TextField;
	public function ParserDelegate(URL:String, textoResultado:TextField) {
		this.textoResultado = textoResultado;
		xml = new XML();
		xml.load(URL);
		// yeeeha!
		xml.onLoad = Delegate.create(this, parse);
	}
	public function parse(success:Boolean) {
		if (success) {
			mostrarXML();
		}
	}
	public function mostrarXML() {
		textoResultado.text = xml.toString();
	}
}

 
import flash.geom.Point;
// sólo 8 ball!
class com.electroduendes.geom.PointUtils{
    /**
     *@deprecated 
     * calcula la distancia entre dos puntos
     * la distancia se calcula con pitágoras: es la raiz cuadrada de los puntos
     * al cuadrado
     * 
     * @ see flash.geom.Point.distance(pt1:Point, pt2:Point) : Number
     *  http://es.wikipedia.org/wiki/Teorema_de_Pit%C3%A1goras
     * 
     */
function distancia(p1:Point, p2:Point):Number{    
        var dx:Number = p1.x - p2.x;
        var dy:Number = p1.y - p2.y;
        return Math.sqrt (dx*dx + dy*dy);
    }
}

/**
*
* com.electroduendes.ejercicios.callback.Perro
* @author      Alejandro Sáncez Marcos
* @version		0.1
* @usage       Tutorial-ejemplo de uso de un callback
* 
* 
* Es muy útil el uso de callbacks como manera de brindar a tu función de compor-
* tamientos diferentes en base a parámetros o otras funciones. 
* 
* En este ejemplo, veremos cómo nuestra clase "perro" despierta al amo 
* por un ladrido. 
* La base estriba en el tipo de dato Function, podremos pasar una función y 
* ejecutarla cuando queramos posteriormente con "apply". 
* 
* 
* Para aquellos que optan por la Orientación a Objetos en su código existen 
* maneras más óptimas, como el paquete EventDispatcher, disponible a partir de 
* la versión 7.2. del Flash Player. Si todavía no dominas al máximo tu orientación a objetos, o
* necesitas dotar de comportamiento simple basado en eventos tus clases,
* este es tu ejemplo.
* 
* Implementación:
* 
* import com.electroduendes.ejercicios.callback.Perro;
* 
* var mastin:Perro = new Perro();
* var miCallback:Object = {func:despertar, ambito:this, parms:[]};
* function despertar() {
*	trace("el amo se despierta");
* }
* mastin.setOnEndLadrido(miCallback);
* mastin.ladrar();
* 
*/
class com.electroduendes.ejercicios.callback.Perro {
 
	//un objeto con tres atributos de tipo Function, ambito, Array
	private var callback : Object = null;
 
	/**
	* @usage		ladra
	*/
	public function ladrar () : Void{
		trace ("guau");
		if (callback != null) 
			//  despachamos la función mediante apply
			callback.func.apply (callback.ambito, callback.parms);		
	}
	/**
	*
	* @usage		setter del callback: le enviamos una función para que 
	* 				la ejecute al fin del ladrido
	* @param		callback que contiene una funcion
	*/
	public function setOnEndLadrido (callback : Object) : Void {
		this.callback = callback;
	}
}

import mx.transitions.*;
import mx.transitions.easing.*;
var animador:TransitionManager = new TransitionManager(mc);
// configuramos nuestros objetos de transiciones
var objBlinds:Object = {type:Blinds, direction:Transition.IN, duration:2, easing:None.easeNone, numStrips:10, dimension:0};
var objFadeTransition:Object = {type:Fade, direction:Transition.IN, duration:3, easing:None.easeNone};
var objFlyTransition:Object = {type:Fly, direction:Transition.IN, duration:3, easing:Elastic.easeOut, startPoint:9};
var objIrisTransition:Object = {type:Iris, direction:Transition.IN, duration:2, easing:Strong.easeOut, startPoint:5, shape:Iris.CIRCLE};
var objPhotoTransition:Object = {type:Photo, direction:Transition.IN, duration:1, easing:None.easeNone};
var objPixelTransition:Object = {type:PixelDissolve, direction:Transition.IN, duration:2, easing:None.easeNone, xSections:10, ySections:10};
var objRotateTransition:Object = {type:Rotate, direction:Transition.IN, duration:3, easing:Strong.easeInOut, ccw:false, degrees:720};
var objSqueezeTransition:Object = {type:Squeeze, direction:Transition.IN, duration:2, easing:Elastic.easeOut, dimension:1};
var objWipeTransition:Object = {type:Wipe, direction:Transition.IN, duration:2, easing:Elastic.easeOut, startPoint:1};
var objZoomTransition:Object = {type:Zoom, direction:Transition.IN, duration:2, easing:Elastic.easeOut};
// rellenamos nuestro combo
combo.addItem({data:objBlinds, label:"Blinds"});
combo.addItem({data:objFadeTransition, label:"Fade"});
combo.addItem({data:objFlyTransition, label:"Fly"});
combo.addItem({data:objIrisTransition, label:"Iris"});
combo.addItem({data:objPhotoTransition, label:"Photo"});
combo.addItem({data:objPixelTransition, label:"PixelDissolve"});
combo.addItem({data:objRotateTransition, label:"Rotate"});
combo.addItem({data:objSqueezeTransition, label:"Squeeze"});
combo.addItem({data:objWipeTransition, label:"Wipe"});
combo.addItem({data:objZoomTransition, label:"Zoom"});
// cargamos el evento change
var obj:Object = new Object();
obj.change = function(evt_obj:Object):Void  {
	var seleccion:Object = evt_obj.target.selectedItem;
	animador.startTransition(seleccion.data);
};
combo.addEventListener("change", obj);
var obj2:Object = new Object();
// cargamos el eveno
obj2.allTransitionsInDone = function(eventObj:Object) {
	trace("evento despachado, fin de la animación");
};
animador.addEventListener("allTransitionsInDone", obj2);